Cython for NumPy users
Author: Dag Seljebotn (any contributions or cleanups of this tutorial welcome, just add your name)
Thanks to Enthought Inc. and the Google Summer of Code program for financing Dag Seljebotn's work on Cython for numerical programming purposes (summer 2008).
Contents
This tutorial is aimed at NumPy users who have no experience with Cython at all. If you have some knowledge of Cython you may want to skip to the Efficient indexing section which explains the new improvements made in summer 2008.
The main scenario considered is NumPy end-use rather than NumPy/SciPy development. The reason is that Cython is not (yet) able to support functions that are generic with respect to datatype and the number of dimensions in a high-level fashion. This restriction is much more severe for SciPy development than more specific, "end-user" functions. See the last section for more information on this.
The style of this tutorial will not fit everybody, so you can also consider:
Robert Bradshaw's slides on Cython for SciPy2008 (a higher-level and quicker introduction)
Basic Cython documentation (see Cython front page).
Note: The fast array access documented below is a completely new feature, and there may be bugs waiting to be discovered. It might be a good idea to do a manual sanity check on the C code Cython generates before using this for serious purposes, at least until some months have passed.
Cython at a glance
Cython is a compiler which compiles Python-like code files to C code. Still, Cython is not a Python to C translator. That is, it doesn't take your full program and "turns it into C" -- rather, the result makes full use of the Python runtime environment. A way of looking at it may be that your code is still Python in that it runs within the Python runtime environment, but rather than compiling to interpreted Python bytecode one compiles to native machine code (but with the addition of extra syntax for easy embedding of faster C-like code).
This has two important consequences:
- Speed. How much depends very much on the program involved though. Typical Python numerical programs would tend to gain very little as most time is spent in lower-level C that is used in a high-level fashion. However for-loop-style programs can gain many orders of magnitude, when typing information is added (and is so made possible as a realistic alternative).
- Easy calling into C code. One of Cython's purposes is to allow easy wrapping of C libraries. When writing code in Cython you can call into C code as easily as into Python code.
Some Python constructs are not yet supported, though making Cython compile all Python code is a stated goal (among the more important omissions are inner functions and generator functions).
Your Cython environment
Using Cython consists of these steps:
Write a .pyx source file
- Run the Cython compiler to generate a C file
- Run a C compiler to generate a compiled library
- Run the Python interpreter and ask it to import the module
However there are several options to automate these steps:
The SAGE mathematics software system provides excellent support for using Cython and NumPy from an interactive command line (like IPython) or through a notebook interface (like Maple/Mathematica). See this documentation.
A version of pyximport is shipped with Cython, so that you can import pyx-files dynamically into Python and have them compiled automatically.
- Cython supports distutils so that you can very easily create build scripts which automate the process, this is the preferred method for full programs.
- Manual compilation (see below)
Note: If using another interactive command line environment than SAGE, like IPython or Python itself, it is important that you restart the process when you recompile the module. It is not enough to issue an "import" statement again.
Installation
Unless you are used to some other automatic method: download Cython (0.9.8.1.1 or later), unpack it, and run the usual python setup.py install. This will install a cython executable on your system. It is also possible to use Cython from the source directory without installing (simply launch cython.py in the root directory).
As of this writing SAGE comes with an older release of Cython than required for this tutorial. So if using SAGE you should download the newest Cython and then execute
$ cd path/to/cython-distro $ path-to-sage/sage -python setup.py install
This will install the newest Cython into SAGE.
Manual compilation
As it is always important to know what is going on, I'll describe the manual method here. First Cython is run:
$ cython yourmod.pyx
This creates yourmod.c which is the C source for a Python extension module. A useful additional switch is -a which will generate a document (yourmod.html) that shows which Cython code translates to which C code line by line.
Then we compile the C file. This may vary according to your system, but the C file should be built like Python was built. Python documentation for writing extensions should have some details. On Linux this often means something like
$ gcc -shared -pthread -fPIC -fwrapv -O2 -Wall -fno-strict-aliasing -I/usr/include/python2.5 -o yourmod.so yourmod.c
gcc should have access to the NumPy C header files so if they are not installed at /usr/include/numpy or similar you may need to pass another option for those.
This creates yourmod.so in the same directory, which is importable by Python by using a normal import yourmod statement.
The first Cython program
The code below does 2D discrete convolution of an image with a filter (and I'm sure you can do better!, let it serve for demonstration purposes). It is both valid Python and valid Cython code. I'll refer to it as both convolve_py.py for the Python version and convolve1.pyx for the Cython version -- Cython uses ".pyx" as its file suffix.
1 from __future__ import division
2 import numpy as np
3 def naive_convolve(f, g):
4 # f is an image and is indexed by (v, w)
5 # g is a filter kernel and is indexed by (s, t),
6 # it needs odd dimensions
7 # h is the output image and is indexed by (x, y),
8 # it is not cropped
9 if g.shape[0] % 2 != 1 or g.shape[1] % 2 != 1:
10 raise ValueError("Only odd dimensions on filter supported")
11 # smid and tmid are number of pixels between the center pixel
12 # and the edge, ie for a 5x5 filter they will be 2.
13 #
14 # The output size is calculated by adding smid, tmid to each
15 # side of the dimensions of the input image.
16 vmax = f.shape[0]
17 wmax = f.shape[1]
18 smax = g.shape[0]
19 tmax = g.shape[1]
20 smid = smax // 2
21 tmid = tmax // 2
22 xmax = vmax + 2*smid
23 ymax = wmax + 2*tmid
24 # Allocate result image.
25 h = np.zeros([xmax, ymax], dtype=f.dtype)
26 # Do convolution
27 for x in range(xmax):
28 for y in range(ymax):
29 # Calculate pixel value for h at (x,y). Sum one component
30 # for each pixel (s, t) of the filter g.
31 s_from = max(smid - x, -smid)
32 s_to = min((xmax - x) - smid, smid + 1)
33 t_from = max(tmid - y, -tmid)
34 t_to = min((ymax - y) - tmid, tmid + 1)
35 value = 0
36 for s in range(s_from, s_to):
37 for t in range(t_from, t_to):
38 v = x - smid + s
39 w = y - tmid + t
40 value += g[smid - s, tmid - t] * f[v, w]
41 h[x, y] = value
42 return h
This should be compiled to produce yourmod.so (for Linux systems). We run a Python session to test both the Python version (imported from .py-file) and the compiled Cython module.
1 In[1]: import numpy as np
2 In[2]: import convolve_py
3 In[3]: convolve_py.naive_convolve(np.array([[1, 1, 1]], dtype=np.int), \
... np.array([[1],[2],[1]], dtype=np.int))
4 Out[3]:
5 array([[1, 1, 1],
6 [2, 2, 2],
7 [1, 1, 1]])
8 In[4]: import convolve1
9 In[4]: convolve1.naive_convolve(np.array([[1, 1, 1]], dtype=np.int), \
... np.array([[1],[2],[1]], dtype=np.int))
10 Out[4]:
11 array([[1, 1, 1],
12 [2, 2, 2],
13 [1, 1, 1]])
14 In [11]: N = 100
15 In [12]: f = np.arange(N*N, dtype=np.int).reshape((N,N))
16 In [13]: g = np.arange(81, dtype=np.int).reshape((9, 9))
17 In [19]: %timeit -n2 -r3 convolve_py.naive_convolve(f, g)
18 2 loops, best of 3: 1.86 s per loop
19 In [20]: %timeit -n2 -r3 convolve1.naive_convolve(f, g)
20 2 loops, best of 3: 1.41 s per loop
There's not such a huge difference yet; because the C code still does exactly what the Python interpreter does (meaning, for instance, that a new object is allocated for each number used). Look at the generated html file and see what is needed for even the simplest statements you get the point quickly. We need to give Cython more information; we need to add types.
Adding types
To add types we use custom Cython syntax, so we are now breaking Python source compatability. Here's convolve2.pyx. Read the comments!
1 from __future__ import division
2 import numpy as np
3 # "cimport" is used to import special compile-time information
4 # about the numpy module (this is stored in a file numpy.pxd which is
5 # currently part of the Cython distribution).
6 cimport numpy as np
7 # We now need to fix a datatype for our arrays. I've used the variable
8 # DTYPE for this, which is assigned to the usual NumPy runtime
9 # type info object.
10 DTYPE = np.int
11 # "ctypedef" assigns a corresponding compile-time type to DTYPE_t. For
12 # every type in the numpy module there's a corresponding compile-time
13 # type with a _t-suffix.
14 ctypedef np.int_t DTYPE_t
15 # The builtin min and max functions works with Python objects, and are
16 # so very slow. So we create our own.
17 # - "cdef" declares a function which has much less overhead than a normal
18 # def function (but it is not Python-callable)
19 # - "inline" is passed on to the C compiler which may inline the functions
20 # - The C type "int" is chosen as return type and argument types
21 # - Cython allows some newer Python constructs like "a if x else b", but
22 # the resulting C file compiles with Python 2.3 through to Python 3.0 beta.
23 cdef inline int int_max(int a, int b): return a if a >= b else b
24 cdef inline int int_min(int a, int b): return a if a <= b else b
25 # "def" can type its arguments but not have a return type. The type of the
26 # arguments for a "def" function is checked at run-time when entering the
27 # function.
28 #
29 # The arrays f, g and h is typed as "np.ndarray" instances. The only effect
30 # this has is to a) insert checks that the function arguments really are
31 # NumPy arrays, and b) make some attribute access like f.shape[0] much
32 # more efficient. (In this example this doesn't matter though.)
33 def naive_convolve(np.ndarray f, np.ndarray g):
34 if g.shape[0] % 2 != 1 or g.shape[1] % 2 != 1:
35 raise ValueError("Only odd dimensions on filter supported")
36 assert f.dtype == DTYPE and g.dtype == DTYPE
37 # The "cdef" keyword is also used within functions to type variables. It
38 # can only be used at the top indendation level (there are non-trivial
39 # problems with allowing them in other places, though we'd love to see
40 # good and thought out proposals for it).
41 #
42 # For the indices, the "int" type is used. This corresponds to a C int,
43 # other C types (like "unsigned int") could have been used instead.
44 # Purists could use "Py_ssize_t" which is the proper Python type for
45 # array indices.
46 cdef int vmax = f.shape[0]
47 cdef int wmax = f.shape[1]
48 cdef int smax = g.shape[0]
49 cdef int tmax = g.shape[1]
50 cdef int smid = smax // 2
51 cdef int tmid = tmax // 2
52 cdef int xmax = vmax + 2*smid
53 cdef int ymax = wmax + 2*tmid
54 cdef np.ndarray h = np.zeros([xmax, ymax], dtype=DTYPE)
55 cdef int x, y, s, t, v, w
56 # It is very important to type ALL your variables. You do not get any
57 # warnings if not, only much slower code (they are implicitly typed as
58 # Python objects).
59 cdef int s_from, s_to, t_from, t_to
60 # For the value variable, we want to use the same data type as is
61 # stored in the array, so we use "DTYPE_t" as defined above.
62 # NB! An important side-effect of this is that if "value" overflows its
63 # datatype size, it will simply wrap around like in C, rather than raise
64 # an error like in Python.
65 cdef DTYPE_t value
66 for x in range(xmax):
67 for y in range(ymax):
68 s_from = int_max(smid - x, -smid)
69 s_to = int_min((xmax - x) - smid, smid + 1)
70 t_from = int_max(tmid - y, -tmid)
71 t_to = int_min((ymax - y) - tmid, tmid + 1)
72 value = 0
73 for s in range(s_from, s_to):
74 for t in range(t_from, t_to):
75 v = x - smid + s
76 w = y - tmid + t
77 value += g[smid - s, tmid - t] * f[v, w]
78 h[x, y] = value
79 return h
At this point, have a look at the generated C code for convolve1.pyx and convolve2.pyx. Click on the lines to expand them and see corresponding C. (Note that this code annotation is currently experimental and especially "trailing" cleanup code for a block may stick to the last expression in the block and make it look worse than it is -- use some common sense).
Especially have a look at the for loops: In convolve1.c, these are ~20 lines of C code to set up while in convolve2.c a normal C for loop is used.
After building this and continuing my (very informal) benchmarks, I get
1 In [21]: import convolve2
2 In [22]: %timeit -n2 -r3 convolve2.naive_convolve(f, g)
3 2 loops, best of 3: 828 ms per loop
Efficient indexing
There's still a bottleneck killing performance, and that is the array lookups and assignments. The []-operator still uses full Python operations -- what we would like to do instead is to access the data buffer directly at C speed.
What we need to do then is to type the contents of the ndarray objects. We do this with a special "buffer" syntax which must be told the datatype (first argument) and number of dimensions ("ndim" keyword-only argument, if not provided then one-dimensional is assumed).
More information on this syntax can be found here.
Showing the changes needed to produce convolve3.pyx only:
1 ...
2 def naive_convolve(np.ndarray[DTYPE_t, ndim=2] f, np.ndarray[DTYPE_t, ndim=2] g):
3 ...
4 cdef np.ndarray[DTYPE_t, ndim=2] h = ...
Usage:
1 In [18]: import convolve3
2 In [19]: %timeit -n3 -r100 convolve3.naive_convolve(f, g)
3 3 loops, best of 100: 11.6 ms per loop
Note the importance of this change.
Gotcha: This efficient indexing only affects certain index operations, namely those with exactly ndim number of typed integer indices. So if v for instance isn't typed, then the lookup f[v, w] isn't optimized. On the other hand this means that you can continue using Python objects for sophisticated dynamic slicing etc. just as when the array is not typed.
Tuning indexing further
The array lookups are still slowed down by two factors:
- Bounds checking is performed.
- Negative indices are checked for and handled correctly.
The code above is explicitly coded so that it doesn't use negative indices, and it (hopefully) always access within bounds. We can add a decorator to disable bounds checking:
1 ...
2 cimport cython
3 @cython.boundscheck(False) # turn of bounds-checking for entire function
4 def naive_convolve(np.ndarray[DTYPE_t, ndim=2] f, np.ndarray[DTYPE_t, ndim=2] g):
5 ...
Now bounds checking is not performed (and, as a side-effect, if you do happen to access out of bounds you will in the best case crash your program and in the worst case corrupt data). It is possible to switch bounds-checking mode in many ways, see compiler directives for more information.
Negative indices are dealt with by ensuring Cython that the indices will be positive, by casting the variables to unsigned integer types (if you do have negative values, then this casting will create a very large positive value instead and you will attempt to access out-of-bounds values). Casting is done with a special <>-syntax. The code below is changed to use either unsigned ints or casting as appropriate:
1 ...
2 cdef int s, t # changed
3 cdef unsigned int x, y, v, w # changed
4 cdef int s_from, s_to, t_from, t_to
5 cdef DTYPE_t value
6 for x in range(xmax):
7 for y in range(ymax):
8 s_from = max(smid - x, -smid)
9 s_to = min((xmax - x) - smid, smid + 1)
10 t_from = max(tmid - y, -tmid)
11 t_to = min((ymax - y) - tmid, tmid + 1)
12 value = 0
13 for s in range(s_from, s_to):
14 for t in range(t_from, t_to):
15 v = <unsigned int>(x - smid + s) # changed
16 w = <unsigned int>(y - tmid + t) # changed
17 value += g[<unsigned int>(smid - s), <unsigned int>(tmid - t)] * f[v, w] # changed
18 h[x, y] = value
19 ...
(In the next Cython release we will likely add a compiler directive or argument to the np.ndarray[]-type specifier to disable negative indexing so that casting so much isn't necesarry; feedback on this is welcome.)
The function call overhead now starts to play a role, so we compare the latter two examples with larger N:
1 In [11]: %timeit -n3 -r100 convolve4.naive_convolve(f, g)
2 3 loops, best of 100: 5.97 ms per loop
3 In [12]: N = 1000
4 In [13]: f = np.arange(N*N, dtype=np.int).reshape((N,N))
5 In [14]: g = np.arange(81, dtype=np.int).reshape((9, 9))
6 In [17]: %timeit -n1 -r10 convolve3.naive_convolve(f, g)
7 1 loops, best of 10: 1.16 s per loop
8 In [18]: %timeit -n1 -r10 convolve4.naive_convolve(f, g)
9 1 loops, best of 10: 597 ms per loop
(Also this is a mixed benchmark as the result array is allocated within the function call.)
Warning!
Speed comes with some cost. Especially it can be dangerous to set typed objects (like f, g and h in our sample code) to None. Setting such objects to None is entirely legal, but all you can do with them is check whether they are None. All other use (attribute lookup or indexing) can potentially segfault or corrupt data (rather than raising exceptions as they would in Python).
The actual rules are a bit more complicated but the main message is clear: Do not use typed objects without knowing that they are not set to None.
More generic code
It would be possible to do
def naive_convolve(object[DTYPE_t, ndim=2] f, ...):
i.e. use object rather than np.ndarray. Under Python 3.0 this can allow your algorithm to work with any libraries supporting the buffer interface; and support for e.g. the Python Imaging Library may easily be added if someone is interested also under Python 2.x.
There is some speed penalty to this though (as one makes more assumptions compile-time if the type is set to np.ndarray, specifically it is assumed that the data is stored in pure strided more and not in indirect mode).
Using the Numpy C API
Occasionally as you are working with Cython and Numpy you will want to be able to use a Numpy entry point directly (for efficiency, for instance). To do so, as with any Numpy-using C extension, you will need to call the Numpy module's initialization function in the module-level of your Cython extension:
cdef extern from "numpy/arrayobject.h":
cdef void import_array()
...
import_array()This will set up the module-level table of Numpy entry points. However, you will also need to tell Numpy about each entry point you wish to use. For instance, if you want an efficient check to see if a Numpy array is a contiguous well behaved "C Array", the macro PyArray_ISCARRAY can be quite useful, similarly, the function PyArray_FromArray can be useful to force an array to be of the correct type. You declare these functions/macros as you would any other externally-defined function/macro in Cython:
cdef extern from "numpy/arrayobject.h":
int PyArray_ISCARRAY( np.ndarray instance )
cdef np.ndarray PyArray_FromArray( np.ndarray, np.dtype, int )
int NPY_CARRAY
int NPY_FORCECASTand can then use them as functions from within your Cython code (we also accept for patches making numpy.pxd support all of the NumPy API). Keep in mind that the Numpy C API has a strange convention where most entry points which take a "dtype" reference "steal" a reference to the dtype (they Py_DECREF the dtype), so if you wish to use one of those entry points you will need to do a Py_INCREF of the dtype before passing it into the entry point:
cdef extern from "Python.h":
cdef void Py_INCREF( object )
...
Py_INCREF( <object> dtype )
return PyArray_FromArray(
instance, dtype, NPY_CARRAY|NPY_FORCECAST
)
The future
These are some points to consider for further development. All points listed here has gone through a lot of thinking and planning already; still they may or may not happen depending on available developer time and resources for Cython.
Support for efficient access to structs/records stored in arrays; currently only primitive types are allowed (but see http://trac.cython.org/cython_trac/ticket/56).
- Support for efficient access to complex floating point types in arrays. The main obstacle here is getting support for efficient complex datatypes in Cython.
Calling NumPy/SciPy functions currently has a Python call overhead; it would be possible to take a short-cut from Cython directly to C. (This does however require some isolated and incremental changes to those libraries; mail the Cython mailing list for details).
Efficient code that is generic with respect to the number of dimensions. This can probably be done today by calling the NumPy C multi-dimensional iterator API directly; however it would be nice to have for-loops over enumerate and ndenumerate on NumPy arrays create efficient code.
- A high-level construct for writing type-generic code, so that one can write functions that work simultaneously with many datatypes. Note however that a macro preprocessor language can help with doing this for now.